Radius.Core/terraformSettings@2025-08-01-preview

Description

The Radius.Core/terraformSettings Resource Type holds reusable Terraform CLI settings that Environments apply when running Terraform Recipes. Its primary use is authenticating to private Terraform registries that host the modules referenced by a Recipe Pack, along with configuring provider installation and injecting environment variables during Recipe execution.

Platform engineers define a Radius.Core/terraformSettings resource once and reference it from any Environment whose Recipes pull modules from a private registry.

Defining Terraform settings

Configure terraformrc.credentials, keyed by registry hostname, to authenticate to a private Terraform registry. Each entry points to a secret whose token key holds the registry token:

extension radius

@description('The Radius Environment ID. Injected automatically by the rad CLI.')
param environment string

resource registrySecret 'Radius.Security/secrets@2025-08-01-preview' = {
  name: 'terraform-registry-token'
  properties: {
    environment: environment
    data: {
      token: { value: 'my-registry-token' }
    }
  }
}

resource terraformRegistry 'Radius.Core/terraformSettings@2025-08-01-preview' = {
  name: 'private-registry'
  properties: {
    terraformrc: {
      credentials: {
        'app.terraform.io': {
          secret: registrySecret.id
        }
      }
    }
  }
}

Two other settings are available: provider installation and environment variables.

Provider installation

In air-gapped or internal environments, use terraformrc.providerInstallation to install providers from a network mirror instead of the public registry. Set the mirror url, optionally narrow it with include or exclude provider address patterns, and use direct to control which providers are still downloaded directly:

resource providerMirror 'Radius.Core/terraformSettings@2025-08-01-preview' = {
  name: 'internal-mirror'
  properties: {
    terraformrc: {
      providerInstallation: {
        networkMirror: {
          url: 'https://terraform.corp.example.com/providers/'
          include: ['*']
        }
        direct: {
          exclude: ['*']
        }
      }
    }
  }
}

Environment variables

Use env to inject environment variables into every Terraform Recipe run, for example to raise the Terraform log level for troubleshooting or to tune CLI behavior:

resource terraformLogging 'Radius.Core/terraformSettings@2025-08-01-preview' = {
  name: 'terraform-logging'
  properties: {
    env: {
      TF_LOG: 'TRACE'
      TF_REGISTRY_CLIENT_TIMEOUT: '15'
    }
  }
}

Deploying Terraform settings

Deploy the settings resource with the rad deploy command:

rad deploy ./terraform-settings.bicep

Referencing Terraform settings from an Environment

Reference the settings from an Environment by setting its terraformSettings property to the resource ID. Every Terraform Recipe run in that Environment then uses the configured registry credentials:

extension radius

resource terraformRegistry 'Radius.Core/terraformSettings@2025-08-01-preview' existing = {
  name: 'private-registry'
}

resource myEnvironment 'Radius.Core/environments@2025-08-01-preview' = {
  name: 'my-environment'
  properties: {
    terraformSettings: terraformRegistry.id
  }
}

Top-Level Properties

Object Properties

terraformrc

terraformrc.credentials

terraformrc.providerInstallation

terraformrc.providerInstallation.direct

terraformrc.providerInstallation.networkMirror